SPARQL 1.1 Update

1.2.1 Language Form

Language forms are show as:

INSERT { ConstructTriples } [ WHERE GroupGraphPattern ]

[] indicates an optional part of the syntax. [] are still used for blank nodes in SPARQL requests.

Italics indicate an item is some syntax element derived from SPARQL. BOLD indicates literal text.

Examples are shown as:

PREFIX dc: <http://purl.org/dc/elements/1.1/>
INSERT { <http://example/egbook3> dc:title  "This is an example title" }

1.2.2 Terminology

When this document uses the words must, must not, should, should not, may and recommended, and the words appear as emphasized text, they must be interpreted as described in RFC 2119 [RFC2119].

The following terms are also in use throughout this document:

• Operation - A single activity to be performed that results in the modification of data in a graph store. e.g. INSERT or DELETE.
• Request - A sequence of one or more operations that are sent to a graph store. When using the SPARQL 1.1 Protocol for RDF a request will be one HTTP POST.

The following terms are also used in this document, and are defined in the SPARQL 1.1 Query Language

• TriplesBlock - A syntactic construct that refers to a set of triples.
• ConstructTriples - Identical to a TriplesBlock, but with an emphasis on defining a particular set of triples, rather than finding them.
• GroupGraphPattern - A syntactic construct for refering to a set of triples, possibly with complex constraints.

4.1.1 INSERT DATA

Insert data into a graph:

INSERT DATA { graph_triples }

Graph triples are defined as:

  graph_triples :: = TriplesBlock | GRAPH <graph_uri> { TriplesBlock }

If no graph is described in the graph_triples, then the default graph is presumed.

Example:

Adding some triples to a graph. This snippet describes two RDF triples to be inserted into the default graph of the RDF store.

PREFIX dc: <http://purl.org/dc/elements/1.1/>
INSERT DATA
{ <http://example/book3> dc:title    "A new book" ;
                         dc:creator  "A.N.Other" .
}

4.1.2 DELETE DATA

Delete data from a graph:

DELETE DATA { graph_triples }

graph_triples are described in INSERT DATA.

Example:

Removing undesired triples from a graph. This operation describes 2 triples to be removed from the default graph of the RDF store.

PREFIX dc: <http://purl.org/dc/elements/1.1/>

DELETE DATA
{ <http://example/bookx> dc:title    "David Copperfield" ;
                         dc:creator  "Edmund Wells" .
}

Example:

This SPARQL 1.1 Update request expands on the previous examples, by including a triple to be deleted and a triple to be added (used here to correct a book title). Also, instead of using the default graph, the requested change happens in the named graph identified by the URI http://example/bookStore.

PREFIX dc: <http://purl.org/dc/elements/1.1/>

DELETE DATA
{ GRAPH <http://example/bookStore> { <http://example/book3>  dc:title  "Fundamentals of Compiler Desing" } }

INSERT DATA
{ GRAPH <http://example/bookStore> { <http://example/book3>  dc:title  "Fundamentals of Compiler Design" } }

4.1.3 INSERT/DELETE

# UPDATE outline syntax : general form:
[ WITH <uri> ]
DELETE { modify_template [ modify_template ]* }
INSERT { modify_template [ modify_template ]* }
WHERE GroupGraphPattern

The modify_template has the following form:

  modify_template :: = ConstructTriples | graph_template
  graph_template ::= GRAPH VarOrIRIRef { ConstructTriples }

The template and pattern forms are as defined in SPARQL for construct templates and graph patterns.

The WITH uri defines the graph that will be modified or matched against for any of the subsequent elements that do not specify a graph explicitly. If not provdided, then the unnamed graph will be assumed.

Following the optional WITH clause are the INSERT and DELETE directives. The deletion of the triples happens before the insertion. The pattern in the WHERE clause is evaluated only once, before the delete part of the operation is performed. The overall processing model is that the pattern is executed, the results used to instantiate the DELETE template, the deletes performed, the results used again to instantiate the INSERT template, and the inserts performed.

The GroupGraphPattern is evaluated as in a SPARQL query SELECT * WHERE GroupGraphPattern and all the named variables are made available to the preceding templates for defining the triples to be inserted or deleted.

The GRAPH <uri> clause in a graph_template names the graph in the graph store to be updated; if omitted, the directive applies to the graph specified by the WITH clause, or the unnamed graph if no WITH clause is present.

If the operation is on a graph that does not exist, an error is generated. Graphs are not created by the graph update operations. The graph management operations have to be used to create new graphs.

Example:

An example to update the graph http://example/addresses to rename all people with the name "Bill" to "William".

PREFIX foaf:  <http://xmlns.com/foaf/0.1/>

WITH <http://example/addresses>
DELETE { ?person foaf:firstName 'Bill' }
INSERT { ?person foaf:firstName 'William' }
WHERE
  { ?person a foaf:Person .
    ?person foaf:firstName 'Bill'
  } 

4.1.4 DELETE

[ WITH <uri> ]
DELETE { modify_template [ modify_template ]* }
[ WHERE GroupGraphPattern ]

The DELETE operation is similar to the INSERT/DELETE operation without an INSERT section.

If the WHERE clause is not present, then the delete template is also treated as the pattern for the effective WHERE clause. Because a template used in this way must also be a valid pattern, it may not contain blank nodes.

If the DELETE template specifies a GRAPH then this will be the graph affected. Otherwise, the operation will be applied to the graph specified in the WITH clause, if one was specified, or the unnamed graph otherwise. If no WHERE clause is present, then the pattern will be matched in the same way: operating on the GRAPH if one is specified, or else the graph in the WITH clause, or the unnamed graph if no other specifications are used.

Example:

The example below has a request to delete all records of old books (with date before year 2000) from the store's default graph

PREFIX dc:  <http://purl.org/dc/elements/1.1/>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>

DELETE
 { ?book ?p ?v }
WHERE
 { ?book dc:date ?date .
   FILTER ( ?date < "2000-01-01T00:00:00-2:00"^^xsd:dateTime )
   ?book ?p ?v
 }

The pattern in WHERE is matched against the graph store analogously to SPARQL - Query. The resulting variable bindings are used to instantiate the triple patterns in the DELETE template analogously to CONSTRUCT. The resulting triples are then removed from the graph store. If the pattern matching fails, no changes occur.

Example:

An example to remove all statements about anything with a first name of "Fred" from the graph http://example/addresses. No WHERE clause is present, meaning that the template also serves as the pattern to be matched.

PREFIX foaf:  <http://xmlns.com/foaf/0.1/>

WITH <http://example/addresses>
DELETE { ?person foaf:firstName 'Fred';
                 ?property      ?value }

Refer also to the final INSERT example, which demonstrates multiple operations, including a DELETE.

4.1.5 INSERT

[ WITH <uri> ]
INSERT { modify_template [ modify_template ]* }
WHERE GroupGraphPattern

The INSERT operation is equivalent to the INSERT/DELETE operation without a specified DELETE section.

If the INSERT template specifies a GRAPH then this will be the graph affected. Otherwise, the operation will be applied to the graph specified in the WITH clause, if one was specified, or the unnamed graph otherwise. If no WHERE clause is present, then the pattern will be matched in the same way: operating on the GRAPH if one is specified, or else the graph in the WITH clause, or the unnamed graph if no other specifications are used.

Example:

This example copies records from one named graph to another named graph based on a pattern.

PREFIX dc:  <http://purl.org/dc/elements/1.1/>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>

INSERT 
  { GRAPH <http://example/bookStore2> { ?book ?p ?v } }
WHERE
  { GRAPH  <http://example/bookStore>
       { ?book dc:date ?date .
         FILTER ( ?date < "2000-01-01T00:00:00-2:00"^^xsd:dateTime )
         ?book ?p ?v
  } }	

Example:

An example to copy records from one named graph to another named graph based on a pattern. All the copied objects that are also classified as Physical Objects are then deleted. This demonstrates two operations in a single request, both of which share common PREFIX definitions.

PREFIX dc:  <http://purl.org/dc/elements/1.1/>
PREFIX dcmitype: <http://purl.org/dc/dcmitype/>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>

INSERT
  { GRAPH <http://example/bookStore2> { ?book ?p ?v } }
WHERE
  { GRAPH  <http://example/bookStore>
     { ?book dc:date ?date . 
       FILTER ( ?date < "2000-01-01T00:00:00-2:00"^^xsd:dateTime )
       ?book ?p ?v
     }
  }

WITH <http://example/bookStore>
DELETE
 { ?book ?p ?v }
WHERE
 { ?book dc:date ?date ;
         dc:type dcmitype:PhysicalObject .
   FILTER ( ?date < "2000-01-01T00:00:00-2:00"^^xsd:dateTime ) 
   ?book ?p ?v
 } 

4.1.6 LOAD

The LOAD operation copies all the triples of a remote graph into the specified graph, or if not specified, the default graph of the Graph Store.

LOAD <documentURI> [ INTO <uri> ]

4.1.7 CLEAR

The CLEAR operations removes all the triples of the specified graph or if not specified, the default graph of the Graph Store. This operation does not remove the graph from the Graph Store.

# Remove all triples.
  CLEAR [ GRAPH <uri> ]

It has the same effect as:

# Remove all triples.
[WITH <uri>] DELETE { ?s ?p ?o } WHERE { ?s ?p ?o }

but is a clearer expression of emptying a graph. If the GRAPH is not specified then this will clear the default graph.

4.2.1 Graph Creation

CREATE [ SILENT ] GRAPH <uri>

This operation creates a new named graph with a name as specified by the URI. After the successful completion of this operation, the new named graph is available for any further graph update operations with INSERT and DELETE operators.

The SPARQL 1.1 Update service generates an error if the graph referred to by the URI already exists unless the keyword SILENT is present, in which case no error is generated and execution of the sequence of SPARQL 1.1 Update operations continues.

4.2.2 Graph Removal

DROP [ SILENT ] GRAPH <uri>

This operation removes the specified named graph from the Graph Store associated with the SPARQL 1.1 Update service endpoint. After successful completion of this operation, the named graph is no more available for further graph update operations.

The SPARQL 1.1 Update service, by default, is expected to generate an error if the specified named graph does not exist. If SILENT is present, this error is ignored and execution of a sequence of SPARQL 1.1 Update operations continues.