The current examples assume a value getter function which maps an item to exactly one atomic value. In practise, typical candidates for such a value getter more often than not may also produce the empty sequence, for example due to the rare but not impossible absence of some XML element or attribute.

Please consider making the example a little more realistic by assuming a value getter function with this signature:
   function(item()) as xs:anyAtomicType?

The implementation of eg:higest, for example, might then look like this:

declare function eg:highest(
                     $seq as item()*, 
                     $getValue as function(item()) as xs:anyAtomicType?)
                 as item()* {
  fold-left(
    $seq,
    (),
    function($highestSoFar as item()*, $item as item()) as item()* {
      let $value := $getValue($item)
      let $highestValue := $highestSoFar[1] ! $getValue(.)
      return
        if (empty($value)) then $highestSoFar
        else if ($value > $highestValue or empty($highestSoFar)) then $item
        else if ($value = $highestValue) then ($highestSoFar, $item)
        else $highestSoFar
      }
  )
};