In the graph http://www.w3.org/People/Berners-Lee/card, find me all subjects (?person) and objects (?name) linked with the foaf:name predicate. Then return all the values of ?name. In other words, find all names mentioned in Tim Berners-Lee's FOAF file.

PREFIX foaf:  <http://xmlns.com/foaf/0.1/>
SELECT ?name
WHERE {
    ?person foaf:name ?name .
}
        

• SPARQL variables start with a ? and can match any node (resource or literal) in the RDF dataset.
• Triple patterns are just like triples, except that any of the parts of a triple can be replaced with a variable.
• The SELECT result clause returns a table of variables and values that satisfy the query.
• Dataset: http://www.w3.org/People/Berners-Lee/card

Find me all the people in Tim Berners-Lee's FOAF file that have names and email addresses. Return each person's URI, name, and email address.

PREFIX foaf:  <http://xmlns.com/foaf/0.1/>
SELECT *
WHERE {
    ?person foaf:name ?name .
    ?person foaf:mbox ?email .
}
        

• We can use multiple triple patterns to retrieve multiple properties about a particular resource
• Shortcut: SELECT * selects all variables mentioned in the query
• Dataset: http://www.w3.org/People/Berners-Lee/card

Try it with HP's ARQ, OpenLink's Virtuoso, or Redland's Rasqal. (Expected results.)

Find me the homepage of anyone known by Tim Berners-Lee.

PREFIX foaf:  <http://xmlns.com/foaf/0.1/>
PREFIX card: <http://www.w3.org/People/Berners-Lee/card#>
SELECT ?homepage
FROM <http://www.w3.org/People/Berners-Lee/card>
WHERE {
    card:i foaf:knows ?known .
    ?known foaf:homepage ?homepage .
}
        

• The FROM keyword lets us specify the target graph in the query itself.
• By using ?known as an object of one triple and the subject of another, we traverse multiple links in the graph.
  

Try it with HP's ARQ, OpenLink's Virtuoso, or Redland's Rasqal. (Expected results.)

Find me 50 example concepts in the DBPedia dataset.

SELECT DISTINCT ?concept
WHERE {
    ?s a ?concept .
} LIMIT 50
        

• LIMIT is a solution modifier that limits the number of rows returned from a query. SPARQL has two other solution modifiers:
  • ORDER BY for sorting query solutions on the value of one or more variables
  • OFFSET, used in conjunction with LIMIT and ORDER BY to take a slice of a sorted solution set (e.g. for paging)
• The SPARQL keyword a is a shortcut for the common predicate rdf:type, giving the class of a resource.
• The DISTINCT modifier eliminates duplicate rows from the query results.

Try it with a DBPedia-specific SPARQL endpoint. (Expected results.)

Find me all landlocked countries with a population greater than 15 million.

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>        
PREFIX type: <http://dbpedia.org/class/yago/>
PREFIX prop: <http://dbpedia.org/property/>
SELECT ?country_name ?population
WHERE {
    ?country a type:LandlockedCountries ;
             rdfs:label ?country_name ;
             prop:populationEstimate ?population .
    FILTER (?population > 15000000) .
}
        

• FILTER constraints use boolean conditions to filter out unwanted query results.
• Shortcut: a semicolon (;) can be used to separate two triple patterns that share the same subject. (?country is the shared subject above.)
• rdfs:label is a common predicate for giving a human-friendly label to a resource.
• Note all the translated duplicates in the results. How can we deal with that?

Try it with one of DBPedia's SPARQL endpoint. (Expected results.)

Find me all landlocked countries with a population greater than 15 million (revisited), with the highest population country first.

PREFIX type: <http://dbpedia.org/class/yago/>
PREFIX prop: <http://dbpedia.org/property/>
SELECT ?country_name ?population
WHERE {
    ?country a type:LandlockedCountries ;
             rdfs:label ?country_name ;
             prop:populationEstimate ?population .
    FILTER (?population > 15000000 && langMatches(lang(?country_name), "EN")) .
} ORDER BY DESC(?population)
        

• lang extracts a literal's language tag, if any
• langMatches matches a language tag against a language range

Try it with a DBPedia-specific SPARQL endpoint. (Expected results.)

Find all Jamendo artists along with their image, home page, and the location they're near.

PREFIX mo: <http://purl.org/ontology/mo/>
PREFIX foaf:  <http://xmlns.com/foaf/0.1/>
SELECT ?name ?img ?hp ?loc
WHERE {
  ?a a mo:MusicArtist ;
     foaf:name ?name ;
     foaf:img ?img ;
     foaf:homepage ?hp ;
     foaf:based_near ?loc .
}
        

• Jamendo has information on about 3,500 artists.
• Trying the query, though, we only get 2,667 results. What's wrong?

Try it with DBTune.org's Jamendo-specific SPARQL endpoint. Be sure to choose SPARQL rather than SeRQL. (Expected results.)

Find all Jamendo artists along with their image, home page, and the location they're near, if any.

PREFIX mo: <http://purl.org/ontology/mo/>
PREFIX foaf:  <http://xmlns.com/foaf/0.1/>
SELECT ?name ?img ?hp ?loc
WHERE {
  ?a a mo:MusicArtist ;
     foaf:name ?name .
  OPTIONAL { ?a foaf:img ?img }
  OPTIONAL { ?a foaf:homepage ?hp }
  OPTIONAL { ?a foaf:based_near ?loc }
}
        

• Not every artist has an image, homepage, or location!
• OPTIONAL tries to match a graph pattern, but doesn't fail the whole query if the optional match fails.
• If an OPTIONAL pattern fails to match for a particular solution, any variables in that pattern remain unbound (no value) for that solution.

Try it with DBTune.org's Jamendo-specific SPARQL endpoint. Be sure to choose SPARQL rather than SeRQL. (Expected results.)

Find me the cellular processes that are either integral to or a refinement of signal transduction.

PREFIX go: <http://purl.org/obo/owl/GO#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX obo: <http://www.obofoundry.org/ro/ro.owl#>
SELECT DISTINCT ?label ?process
WHERE {
  { ?process obo:part_of go:GO_0007165 } # integral to
      UNION
  { ?process rdfs:subClassOf go:GO_0007165 } # refinement of
  ?process rdfs:label ?label
}

• The UNION keyword forms a disjunction of two graph patterns. Solutions to both sides of the UNION are included in the results.
• The URI go:GO_0007165 is the identifier for signal transduction in the Gene Ontology
• N.B. Cell-surface-receptor-linked signal transduction is a refinement (subclass) of signal transduction

Try it with the HCLS knowledgebase SPARQL endpoint. (Expected results.)

Find me people who have been involved with at least three ISWC or ESWC conference events.

SELECT DISTINCT ?person
WHERE {
    ?person foaf:name ?name .
    GRAPH ?g1 { ?person a foaf:Person }
    GRAPH ?g2 { ?person a foaf:Person }
    GRAPH ?g3 { ?person a foaf:Person }
    FILTER(?g1 != ?g2 && ?g1 != ?g3 && ?g2 != ?g3) .
}     
        

• The GRAPH ?g construct allows a pattern to match against one of the named graphs in the RDF dataset. The URI of the matching graph is bound to ?g (or whatever variable was actually used).
• N.B. The FILTER assures that we're finding a person who occurs in three distinct graphs.
• N.B. The Web interface we use for this SPARQL query defines the foaf: prefix, which is why we omit it here.

Try it with the data.semanticweb.org SPARQL endpoint. (Expected results.)

Convert FOAF data to VCard data.

PREFIX vCard: <http://www.w3.org/2001/vcard-rdf/3.0#>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
CONSTRUCT { 
  ?X vCard:FN ?name .
  ?X vCard:URL ?url .
  ?X vCard:TITLE ?title .
}FROM <http://www.w3.org/People/Berners-Lee/card>
WHERE { 
  OPTIONAL { ?X foaf:name ?name . FILTER isLiteral(?name) . }
  OPTIONAL { ?X foaf:homepage ?url . FILTER isURI(?url) . }
  OPTIONAL { ?X foaf:title ?title . FILTER isLiteral(?title) . }
}
        

• CONSTRUCT is an alternative SPARQL result clause to SELECT. Instead of returning a table of result values, CONSTRUCT returns an RDF graph.
• The result RDF graph is created by taking the results of the equivalent SELECT query and filling in the values of variables that occur in the CONSTRUCT template.
• Triples are not created in the result graph for template patterns that involve an unbound variable.

Try it with HP's ARQ or OpenLink's Virtuoso. (Expected results.)

Is the Amazon river longer than the Nile River?

PREFIX prop: <http://dbpedia.org/property/>
ASK
{
  <http://dbpedia.org/resource/Amazon_River> prop:length ?amazon .
  <http://dbpedia.org/resource/Nile> prop:length ?nile .
  FILTER(?amazon > ?nile) .
}       
        

• The ASK result clause simply returns true or false depending on whether or not the query pattern has any matches in the dataset.
• As with SELECT queries, the boolean result is (by default) encoded in an SPARQL Results Format XML document.
• Shortcut: the WHERE keyword is optional--not only in ASK queries but in all SPARQL queries.

Try it with the Virtuoso DBPedia SPARQL endpoint. (Expected results. - or are they??)

Tell me whatever you'd like to tell me about the Ford Motor Company.

PREFIX foaf:  <http://xmlns.com/foaf/0.1/>
DESCRIBE ?ford WHERE {
  ?ford foaf:name "FORD MOTOR CO" .
}
        

• The DESCRIBE query result clause allows the server to return whatever RDF it wants that describes the given resource(s).
• Because the server is free to interpret DESCRIBE as it sees fit, DESCRIBE queries are not interoperable.
• Common implementations include concise-bounded descriptions, named graphs, minimum self-contained graphs, and more.

Try it with the EDGAR-specific SPARQL endpoint. (Expected results.)

Find me members of the Senate Armed Service committee's Strategic Forces subcommittee who do not also serve on the Personnel subcommittee.

PREFIX foaf:  <http://xmlns.com/foaf/0.1/>
SELECT ?name 
WHERE {
  # find members in the Strategic Forces subcommittee
  <http://www.rdfabout.com/rdf/usgov/congress/committees/SenateArmedServices/StrategicForces> 
    foaf:member ?member .
  OPTIONAL {
    # find out if this same member is in the Personnel 
    # subcommittee - but call him/her something different 
    # (?member2)
    <http://www.rdfabout.com/rdf/usgov/congress/committees/SenateArmedServices/Personnel> 
      foaf:member ?member2 .
    FILTER (?member2 = ?member) .
  }
  # keep only those rows that failed to find a ?member2 
  # (member of Personnel subcommittee)
  FILTER (!bound(?member2)) .
  ?member foaf:name ?name .
}

• Together, OPTIONAL and the !bound(...) filter allow us to query for things that are not asserted in the RDF dataset.
• A similar technique allows for various types of universally quantified queries. (E.g. min or max value of a predicate.) See this frequently asked question.

Try it with the GovTrack-specific SPARQL endpoint. (Expected results.)

What are the top interests of LiveJournal users interested in Harry Potter?

PREFIX foaf: <http://xmlns.com/foaf/0.1/>
SELECT ?interest COUNT(*) AS ?count where
  {
    ?p foaf:interest <http://www.livejournal.com/interests.bml?int=harry+potter> .
    ?p foaf:interest ?interest
  }
GROUP BY ?interest ORDER BY DESC(COUNT(*)) LIMIT 10

• Some SPARQL engines support aggregate functions: functions that calculate a single value from a set of results.
• Aggregate functions include: COUNT, MIN, MAX, SUM, ...
• Some implementations combine aggregate functions with a GROUP BY clause that breaks the query's result set into groups before applying the aggregate function(s).

Try it with the Virtuoso Linked Open Data endpoint. (Expected results.)

Find me countries with 'Republic' in their name that were established before 1920.

PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>        
PREFIX type: <http://dbpedia.org/class/yago/>
PREFIX prop: <http://dbpedia.org/property/>
SELECT ?lbl ?est
WHERE {
  ?country rdfs:label ?lbl .
  FILTER(bif:contains(?lbl, "Republic")) .
  ?country a type:Country108544813 ;
      prop:establishedDate ?est .
  FILTER(?est < "1920-01-01"^^xsd:date) .
}
        

• OpenLink's Virtuoso uses an extension filter function, bif:contains to filter literal values against a free-text index. Other implementations use other techniques.

Try it with the Virtuoso DBPedia SPARQL endpoint. (Expected results.)