<!--
  Compare ed:issue elements in xml2rfc version of spec with the
  issues list at <http://www.w3.org/Protocols/HTTP/1.1/rfc2616bis/issues/index.xml>
-->

<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                version="1.0"
                xmlns:ed="http://greenbytes.de/2002/rfcedit"
                xmlns:i="http://www.w3.org/Protocols/HTTP/1.1/rfc2616bis/issues/"
>

<xsl:output encoding="ASCII" method="text"/>

<xsl:variable name="issues" select="document('http://www.w3.org/Protocols/HTTP/1.1/rfc2616bis/issues/index.xml')"/>

<xsl:template match="/">
  <xsl:text>&#10;Open Issues:&#10;</xsl:text>
  <xsl:apply-templates select="//ed:issue[@status!='closed']">
    <xsl:sort select="@name"/>
  </xsl:apply-templates>

  <xsl:text>&#10;Closed Issues:&#10;</xsl:text>
  <xsl:apply-templates select="//ed:issue[@status='closed']">
    <xsl:sort select="@name"/>
  </xsl:apply-templates>

  <xsl:text>&#10;Open Issues from Issues List not included:&#10;</xsl:text>
  <xsl:variable name="doc" select="/"/>
  <xsl:for-each select="$issues//i:issue[@status!='closed']">
    <xsl:variable name="href" select="concat('http://www.w3.org/Protocols/HTTP/1.1/rfc2616bis/issues/#',@id)"/>
    <xsl:if test="count($doc//ed:issue[@href=$href or @alternate-href=$href])=0">
      <xsl:value-of select="@id"/>
      <xsl:text> (</xsl:text>
      <xsl:value-of select="i:title"/>
      <xsl:text>)</xsl:text>
      <xsl:text>&#10;</xsl:text>
    </xsl:if>
  </xsl:for-each>

</xsl:template>

<xsl:template match="ed:issue">
  <xsl:value-of select="@name"/>
  <xsl:text>: </xsl:text>
  <xsl:choose>
    <xsl:when test="starts-with(@href,'http://www.w3.org/Protocols/HTTP/1.1/rfc2616bis/issues/#') or starts-with(@alternate-href,'http://www.w3.org/Protocols/HTTP/1.1/rfc2616bis/issues/#')">
      <xsl:variable name="anch">
        <xsl:choose>
          <xsl:when test="@alternate-href">
            <xsl:value-of select="substring-after(@alternate-href,'http://www.w3.org/Protocols/HTTP/1.1/rfc2616bis/issues/#')"/>
          </xsl:when>
          <xsl:otherwise>
            <xsl:value-of select="substring-after(@href,'http://www.w3.org/Protocols/HTTP/1.1/rfc2616bis/issues/#')"/>
          </xsl:otherwise>
        </xsl:choose>
      </xsl:variable>
      <xsl:variable name="issue" select="$issues//i:issue[@id=$anch]"/>
      <xsl:text>WG status </xsl:text>
      <xsl:value-of select="$issue/@status"/>
      <xsl:text> (</xsl:text>
      <xsl:value-of select="$anch"/>
      <xsl:text>)</xsl:text>
    </xsl:when>
    <xsl:otherwise>
      <xsl:text>WARNING: missing from rfc2616bis issues list</xsl:text>
    </xsl:otherwise>
  </xsl:choose>
  <xsl:text>&#10;</xsl:text>
</xsl:template>

</xsl:transform>