PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX Person: <http://hospital.example/DB/Person#>
PREFIX Sex_DE: <http://hospital.example/DB/Sex_DE#>
PREFIX Item_Medication: <http://hospital.example/DB/Item_Medication#>
PREFIX Medication: <http://hospital.example/DB/Medication#>
PREFIX Medication_DE: <http://hospital.example/DB/Medication_DE#>
PREFIX NDCcodes: <http://hospital.example/DB/NDCcodes#>

PREFIX hl7: <http://www.hl7.org/v3ballot/xml/infrastructure/vocabulary/vocabulary#>
PREFIX spl: <http://www.hl7.org/v3ballot/xml/infrastructure/vocabulary/vocabulary#>

CONSTRUCT {
?dbhl_person
    a					  hl7:Person ;
    hl7:entityName			  ?dbhl_middleName ;
    hl7:livingSubjectBirthTime		  ?dbhl_dob ;
    hl7:administrativeGenderCodePrintName ?dbhl_sex ;
    hl7:substanceAdministration		  [
	a	       hl7:SubstanceAdministration ;
 	hl7:consumable [
	    hl7:displayName	 ?dbhl_takes ;
	    spl:activeIngredient [
		spl:classCode ?dbhl_ingred
	    ]
	] ;
	hl7:effectiveTime [
	    hl7:start ?dbhl_indicDate
	    # hl7:end   (?dbhl_indicDate + ?dbhl_indicDuration)
	]
    ] .
} WHERE {
  ?dbhl_person     Person:MiddleName		     ?dbhl_middleName ;
              Person:DateOfBirth	     ?dbhl_dob ;
              Person:SexDE		     ?dbhl_sexEntry   .

  OPTIONAL {
              ?dbhl_sexEntry   Sex_DE:EntryName   ?dbhl_sex .
  }

  OPTIONAL {
  ?dbhl_indicItem  Item_Medication:PatientID	     ?dbhl_person ;
              Item_Medication:PerformedDTTM  ?dbhl_indicDate ;
              Item_Medication:EntryName	     ?dbhl_takes .
  ?dbhl_indicMed   Medication:ItemID		     ?dbhl_indicItem ;
              Medication:DaysToTake	     ?dbhl_indicDuration ;
              Medication:MedDictDE	     ?dbhl_indicDE .
  ?dbhl_indicDE    Medication_DE:NDC		     ?dbhl_indicNDC .
  }

  OPTIONAL {
  ?dbhl_indicCode  NDCcodes:NDC         ?dbhl_indicNDC ;
              NDCcodes:ingredient  ?dbhl_ingred .
  }
} LIMIT 30