<xsl:transform
 version="1.0"
 xmlns:xsl  ="http://www.w3.org/1999/XSL/Transform"
 xmlns:h    ="http://www.w3.org/1999/xhtml"
 xmlns:r    ="http://www.w3.org/1999/02/22-rdf-syntax-ns#"
 xmlns:cal  ="http://www.w3.org/2002/12/cal/icaltzd#"
 xmlns:dc   ="http://purl.org/dc/elements/1.1/"
 >

<xsl:output method="xml" indent="yes"/>

<xsl:param name="Source"
	   select='"http://web.mit.edu/hr/empservices/mit_holidays.html"'/>

<xsl:template match="h:html">
  <r:RDF>
    <cal:Vcalendar r:about="">
      <!-- parameterize the source? -->
      <dc:source r:resource='{$Source}'/>
      <xsl:apply-templates />
    </cal:Vcalendar>
  </r:RDF>
</xsl:template>

<xsl:template match='h:table[h:tr/h:td[2] = "Day"]'>
  <xsl:for-each select='h:tr[not(h:td[2] ="Day")]'>
    <xsl:variable name="label" select="h:td[1]"/>
    <xsl:variable name="rule" select="h:td[2]"/>
    <xsl:variable name="date" select="h:td[3]"/>

    <xsl:if test='$label
	    and $rule
	    and $date'>
      <cal:component>
	<cal:Vevent>
	  <cal:summary><xsl:value-of select='$label'/></cal:summary>

	  <cal:dtstart r:datatype="http://www.w3.org/2001/XMLSchema#date">
	    <xsl:call-template name="grokDate">
	      <xsl:with-param name="longDate" select='$date'/>
	    </xsl:call-template>
	  </cal:dtstart>
	  
	  <cal:description>
	    <xsl:value-of select='$rule'/>
	    <xsl:text>: </xsl:text>
	    <xsl:value-of select='$date'/>
	  </cal:description>

	  <cal:url r:resource='{$Source}'/>
	</cal:Vevent>
      </cal:component>
    </xsl:if>
  </xsl:for-each>

  <xsl:if test="0">
    <xsl:message>
      found table: <xsl:value-of select="."/>
    </xsl:message>
  </xsl:if>

</xsl:template>

<xsl:template name="grokDate">
  <xsl:param name="longDate"/>

  <xsl:variable name="mdy"
		select='normalize-space(substring-after($longDate, ","))'/>
  <xsl:variable name="month">
    <xsl:call-template name="monthIndex">
      <xsl:with-param name="name" select='substring-before($mdy, " ")'/>
    </xsl:call-template>
  </xsl:variable>
  <xsl:variable name="dy" select='substring-after($mdy, " ")'/>
  <xsl:variable name="day" select='number(substring-before($dy, ","))'/>
  <xsl:variable name="year" select='number(normalize-space(substring-after($dy, ",")))'/>

  <xsl:value-of select='concat(
			format-number($year, "0000"), "-",
			format-number($month, "00"), "-",
			format-number($day, "00"))'/>
</xsl:template>


<xsl:template name="monthIndex">
  <!-- cribbed from schedScrape.xsl,v 1.9 2004/02/22 21:11:26 -->
  <xsl:param name="name"/>

  <xsl:variable name="mmm">
    <xsl:value-of select='substring(translate($name, "abcdefghijklmnopqrstuvwxyz", "ABCDEFGHIJKLMNOPQRSTUVWXYZ"), 1, 3)'/>
  </xsl:variable>
  <xsl:choose>
    <xsl:when test='$mmm = "JAN"'>
      <xsl:value-of select='1'/>
    </xsl:when>

    <xsl:when test='$mmm = "FEB"'>
      <xsl:value-of select='2'/>
    </xsl:when>

    <xsl:when test='$mmm = "MAR"'>
      <xsl:value-of select='3'/>
    </xsl:when>

    <xsl:when test='$mmm = "APR"'>
      <xsl:value-of select='4'/>
    </xsl:when>

    <xsl:when test='$mmm = "MAY"'>
      <xsl:value-of select='5'/>
    </xsl:when>

    <xsl:when test='$mmm = "JUN"'>
      <xsl:value-of select='6'/>
    </xsl:when>

    <xsl:when test='$mmm = "JUL"'>
      <xsl:value-of select='7'/>
    </xsl:when>

    <xsl:when test='$mmm = "AUG"'>
      <xsl:value-of select='8'/>
    </xsl:when>

    <xsl:when test='$mmm = "SEP"'>
      <xsl:value-of select='9'/>
    </xsl:when>

    <xsl:when test='$mmm = "OCT"'>
      <xsl:value-of select='10'/>
    </xsl:when>

    <xsl:when test='$mmm = "NOV"'>
      <xsl:value-of select='11'/>
    </xsl:when>

    <xsl:when test='$mmm = "DEC"'>
      <xsl:value-of select='12'/>
    </xsl:when>

  </xsl:choose>

</xsl:template>

<!-- don't pass text thru -->
<xsl:template match="text()|@*">
</xsl:template>

</xsl:transform>