This is a BNF grammar in a yacc-ish syntax. It's used for constructing the
grammar section of the SPARQL specification.

$Id: grammar.yy,v 1.5 2004/11/28 08:28:39 eric Exp $

INSTRUCTIONS:
Mark (\C-SPACE) after this header.
Then go to the bottom and ESC | ../../../../2004/05/06-Algae/prod2Table sparql
and past the results between the MARKER comments

%TOKENS
<SELECT>:      "select"
;
<DISTINCT>:    "distinct"
;
#<LIMIT>:       "limit"
;
<DESCRIBE>:    "describe"
;
<CONSTRUCT>:   "construct"
;
<ASK>:         "ask"
;
#<UNSAID>:      "unsaid"
;
<SOURCE>:      "source"
;
<FROM>:        "from"
;
<WHERE>:       "where"
;
<AND>:         "and"
;
#<OR>:          "or"
;
<UNION>:       "union"
;
<PREFIX>:      "prefix"
;
<OPTIONAL>:    "optional"
;
#<FOR>:         "for"
;
<STR_EQ>: "eq"
;
<STR_NE>: "ne"
;

<LPAREN>:    "("
;
<RPAREN>:    ")"
;

<LBRACE>:    "{"
;
<RBRACE>:    "}"
;
<LBRACKET>:  "["
;
<RBRACKET>:  "]"
;
#<SEMICOLON>: ";"
;
<COMMA>:     ","
;
#<DOT>:       "."
;

#<ASSIGN>: "="
;
<GT>: "&gt;"
;
<LT>: "&lt;"
;
<BANG>: "!"
;
<TILDE>: "~"
;
#<HOOK>: "?"
;
<COLON>: ":"
;
<EQ>: "=="
;
<NEQ>: "!="
;
<LE>: "&lt;="
;
<GE>: "&gt;="
;
<SC_OR>: "||"
;
<SC_AND>: "&amp;&amp;"
;
#<INCR>: "++"
;
#<DECR>: "--"
;
<PLUS>: "+"
;
<MINUS>: "-"
;
<STAR>: "*"
;
<SLASH>: "/"
;
<AMP>: "&amp;"
;
<REM>: "%"
;
#<LSHIFT>: "&lt;&lt;"
;
#<RSIGNEDSHIFT>: "&gt;&gt;"
;
#<RUNSIGNEDSHIFT>: "&gt;&gt;&gt;"
;
<STR_MATCH>: "=~"
;
<STR_NMATCH>: "!~"
;
<DATATYPE>: "^^"
;
<AT>: "@"
;

%%
<tbody><tr><td colspan="4" class="grammarSection"><h3><a id="productions" name="productions">Productions</a>:</h3></td></tr></tbody>

Query:	PrefixDecl* ReportFormat PrefixDecl* FromClause? WhereClause?
;
ReportFormat:	<SELECT> <DISTINCT>? <VAR> ( CommaOpt <VAR> )*
	 | <SELECT> <DISTINCT>? <STAR>
	 | <CONSTRUCT> ConstructPattern
	 | <CONSTRUCT> <STAR>
	 | <DESCRIBE> VarOrURI ( CommaOpt VarOrURI )*
	 | <DESCRIBE> <STAR>
	 | <ASK>
;
FromClause:	<FROM> FromSelector ( CommaOpt FromSelector )*
;
FromSelector:	URI
;
WhereClause:	<WHERE> GraphPattern
;
SourceGraphPattern:	<SOURCE> <STAR> PatternElement
	 | <SOURCE> VarOrURI PatternElement
;
OptionalGraphPattern:	<OPTIONAL> PatternElement
	 | <LBRACKET> GraphPattern <RBRACKET>
;
GraphPattern:	GraphAndPattern (<UNION> GraphAndPattern)*
;
GraphAndPattern:	PatternElement+
;
PatternElement:	TriplePattern
	 | GroupGraphPattern
	 | SourceGraphPattern
	 | OptionalGraphPattern
	 | <AND>? Expression
;
GroupGraphPattern:	<LBRACE> GraphPattern <RBRACE>
;
TriplePattern:	<LPAREN> VarOrURI CommaOpt VarOrURI CommaOpt VarOrLiteral <RPAREN>
;
ConstructPattern:	ConstructElement+
;
ConstructElement:	TriplePattern
			| <LBRACE> ConstructPattern <RBRACE>
;
VarOrURI:	<VAR>
	 | URI
;
VarOrLiteral:	<VAR>
	 | Literal
;
PrefixDecl:	<PREFIX> <NCNAME> <COLON> QuotedURI
	 | <PREFIX> <COLON> QuotedURI
;
Expression:	ConditionalOrExpression
;
ConditionalOrExpression:	ConditionalAndExpression ( <SC_OR> ConditionalAndExpression )*
;
ConditionalAndExpression:	ValueLogical ( <SC_AND> ValueLogical )*
;
ValueLogical:	StringEqualityExpression
;
StringEqualityExpression:	EqualityExpression StringComparitor*
;
StringComparitor:	<STR_EQ> EqualityExpression
	 | <STR_NE> EqualityExpression
	 | <STR_MATCH> <PATTERN_LITERAL>
	 | <STR_NMATCH> <PATTERN_LITERAL>
;
EqualityExpression:	RelationalExpression RelationalComparitor?
;
RelationalComparitor:	<EQ> RelationalExpression
	 | <NEQ> RelationalExpression
;
RelationalExpression:	AdditiveExpression NumericComparitor?
;
NumericComparitor:	<LT> AdditiveExpression
	 | <GT> AdditiveExpression
	 | <LE> AdditiveExpression
	 | <GE> AdditiveExpression
;
AdditiveExpression:	MultiplicativeExpression AdditiveOperation*
;
AdditiveOperation:	<PLUS> MultiplicativeExpression
	 | <MINUS> MultiplicativeExpression
;
MultiplicativeExpression:	UnaryExpression MultiplicativeOperation*
;
MultiplicativeOperation:	<STAR> UnaryExpression
	 | <SLASH> UnaryExpression
	 | <REM> UnaryExpression
;
UnaryExpression:	UnaryExpressionNotPlusMinus
;
UnaryExpressionNotPlusMinus:	( <TILDE> | <BANG> ) UnaryExpression
 	 |  PrimaryExpression
;
PrimaryExpression:	<VAR>
	 | Literal
	 | FunctionCall
	 | <LPAREN> Expression <RPAREN>
;
FunctionCall:	<AMP> <QNAME> <LPAREN> ArgList? <RPAREN>
;
ArgList:	VarOrLiteral ( <COMMA> VarOrLiteral )*
;
Literal:	URI
 	|  NumericLiteral
 	|  TextLiteral
;
NumericLiteral:	<INTEGER_LITERAL>
 	|  <FLOATING_POINT_LITERAL>
;
TextLiteral:	String <LANG>? ( <DATATYPE> URI )?
;
String:		<STRING_LITERAL1>
	 | <STRING_LITERAL2>
;
URI:		QuotedURI
 	 |  QName
;
QName:		<QNAME>
;
QuotedURI:	<URI>
;
CommaOpt:	<COMMA>?
;

<tbody><tr><td colspan="4" class="grammarSection"><h3><a id="terminals" name="terminals">Terminals</a>:</h3><p>These terminals are further factored for readability.</p></td></tr></tbody>

<URI>:		"<" <NCCHAR1> (~[">"," "])* ">"
;
<QNAME>:	(<NCNAME>)? ":" <NCNAME>
;
<VAR>:		"?" <NCNAME>
;
<LANG>:		<AT> <A2Z><A2Z> ("-" <A2Z><A2Z>)?
;
<A2Z>:		["a"-"z","A"-"Z"]>
;

<INTEGER_LITERAL>:	(["+","-"])? <DECIMAL_LITERAL> (["l","L"])?
                      | <HEX_LITERAL> (["l","L"])?
;
<DECIMAL_LITERAL>:	<DIGITS>
;
<HEX_LITERAL>:		"0" ["x","X"] (["0"-"9","a"-"f","A"-"F"])+
;

<FLOATING_POINT_LITERAL>:	(["+","-"])? (["0"-"9"])+ "." (["0"-"9"])* (<EXPONENT>)?
      | "." (["0"-"9"])+ (<EXPONENT>)?
      | (["0"-"9"])+ <EXPONENT>
;
<EXPONENT>:		["e","E"] (["+","-"])? (["0"-"9"])+
;
# Single quoted string
<STRING_LITERAL1>:	"'" ( (~["'","\\","\n","\r"]) | ("\\" ~["\n","\r"]) )* "'"
;
# Double quoted string
<STRING_LITERAL2>:	"\"" ( (~["\"","\\","\n","\r"]) | ("\\"  ~["\n","\r"]) )* "\""
;
<DIGITS>:		(["0"-"9"])
;

<PATTERN_LITERAL>:	[m]/pattern/[i][m][s][x]
;

<NCCHAR1>:		["A"-"Z"] 
	| "_" | ["a"-"z"] 
	| ["\u00C0"-"\u02FF"]  
	| ["\u0370"-"\u037D"] 
	| ["\u037F"-"\u1FFF"] 
	| ["\u200C"-"\u200D"] 
	| ["\u2070"-"\u218F"] 
	| ["\u2C00"-"\u2FEF"] 
	| ["\u3001"-"\uD7FF"] 
	| ["\uF900"-"\uFFFF"] 
;
<NCNAME>:		<NCCHAR1> (<NCCHAR1> | "." | "-" | ["0"-"9"] | "\u00B7" )*
;